《VB真是想不到系列》
    每次看大師的東西到了精彩之處，我就會拍案叫絕："哇噻，真是想不到！"。在經過很多次這種感慨之后，我發現只要我們動了腦筋，我們自己也能有讓別人想不到的東西。于是想到要把這些想不到的東拿出來和大家一起分享，希望拋磚引玉，能引出更多讓人想不到的東西。
   
                  VB真是想不到系列之二：VB《葵花寶典》--指針技術
關鍵字：VB、指針、動態內存分配、效率、安全
難度：中級至高級
要求：熟悉VB，掌握基本的C，了解匯編，了解內存分配原理。
    想當年東方不敗，黑木崖密室一戰，僅憑一根繡花針獨戰四大高手，神出鬼沒，堪稱天下武林第一高手。若想成為VB里的東方不敗，熟習VB《葵花寶典》，掌握VB指針技術，乃是不二的法門。
    欲練神功，引刀……，其實掌握VB指針技術，并不需要那么痛苦。因為說穿了，也就那么幾招，再勤加練習，終可至神出鬼沒之境。廢話少說，讓我們先從指針的定義說起。
   
    一、指針是什么？
    不需要去找什么標準的定義，它就是一個32位整數，在C語言和在VB里都可以用Long類型來表示。在32位Windows平臺下它和普通的32位長整型數沒有什么不同，只不過它的值是一個內存地址，正是因為這個整數象針一樣指向一個內存地址，所以就有了指針的概念。
    有統計表明，很大一部分程序缺陷和內存的錯誤訪問有關。正是因為指針直接和內存打交道，所以指針一直以來被看成一個危險的東西。以至于不少語言，如著名的JAVA，都不提供對指針操作的支持，所有的內存訪問方面的處理都由編譯器來完成。而象C和C++，指針的使用則是基本功，指針給了程序員極大的自由去隨心所欲地處理內存訪問，很多非常巧妙的東西都要依靠指針技術來完成。
    關于一門高級的程序設計語言是不是應該取消指針操作，關于沒有指針操作算不算一門語言的優點，我在這里不討論，因為互聯網上關于這方面的沒有結果的討論，已經造成了占用幾個GB的資源。無論最終你是不是要下定決心修習指針技術《葵花寶典》，了解這門功夫總是有益處的。
    注意：在VB里，官方是不鼓勵使用什么指針的，本文所講的任何東西你都別指望取得官方的技術支持，一切都要靠我們自己的努力，一切都更刺激！
    讓我們開始神奇的VB指針探險吧！

   順便提一下，聽說VB.NET里沒有這幾個函數，但只要還能調用API，我們就可以試試上面的幾個聲明，這樣在VB.NET里我們一樣可以進行指針操作。
    但是請注意，如果通過API調用來使用VarPtr，整個程序二SwapPtr將比原來使用內置VarPtr函數時慢6倍。）
    如果你喜歡刨根問底，那么下面就是VarPtr函數在C和匯編語言里的樣子：
    在C里樣子是這樣的：
    long VarPtr(void* pv){
        return (long)pv;
    }
    所對就的匯編代碼就兩行：
    mov         eax,dword ptr [esp+4]
    ret         4           '彈出棧里參數的值并返回。
    之所以讓大家了解VarPtr的具體實現，是想告訴大家它的開銷并不大，因為它們不過兩條指令，即使加上參數賦值、壓棧和調用指令，整個獲取指針的過程也就六條指令。當然，同樣的功能在C語言里，由于語言的直接支持，僅需要一條指令即可。但在VB里，它已經算是最快的函數了，所以我們完全不用擔心使用VarPtr會讓我們失去效率！速度是使用指針技術的根本要求。
    一句話，VarPtr返回的是變量所在處的內存地址，也可以說返回了指向變量內存位置的指針，它是我們在VB里處理指針最重要的武器之一。

3、ByVal和ByRef
    ByVal傳遞的參數值，而ByRef傳遞的參數的地址。在這里，我們不用去區別傳指針/傳地址/傳引用的不同，在VB里，它們根本就是一個東西的三種不同說法，即使VB的文檔里也有地方在混用這些術語（但在C++里的確要區分指針和引用）
    初次接觸上面的程序二SwapPtr的朋友，一定要搞清在里面的CopyMemory調用中，在什么地方要加ByVal，什么地方不加（不加ByVal就是使用VB缺省的ByRef）
    準確的理解傳值和傳地址（指針）的區別，是在VB里正確使用指針的基礎。
    現在一個最簡單的實驗來看這個問題，如下面的程序三：
【程序三】：'體會ByVal和ByRef
    Sub TestCopyMemory()
        Dim k As Long
        k = 5
Note:   CopyMemory ByVal VarPtr(k), 40000, 4
        Debug.Print k
    End Sub
    上面標號Note處的語句的目的，是將k賦值為40000，等同于語句k=40000，你可以在"立即"窗口試驗一下，會發現k的值的確成了40000。
    實際上上面這個語句，翻譯成白話，就是從保存常數40000的臨時變量處拷貝4個字節到變量k所在的內存中。
    現在我們來改變一個Note處的語句，若改成下面的語句：
Note2:   CopyMemory ByVal VarPtr(k), ByVal 40000, 4
    這句話的意思就成了，從地址40000拷貝4個字節到變量k所在的內存中。由于地址40000所在的內存我們無權訪問，操作系統會給我們一個Access Violation內存越權訪問錯誤，告訴我們"試圖讀取位置0x00009c40處內存時出錯，該內存不能為'Read'"。
    我們再改成如下的語句看看。
Note3:   CopyMemory VarPtr(k), 40000, 4
    這句話的意思就成了，從保存常數40000的臨時變量處拷貝4個字節到到保存變量k所在內存地址值的臨時變量處。這不會出出內存越權訪問錯誤，但k的值并沒有變。
    我們可以把程序改改以更清楚的休現這種區別，如下面的程序四：
【程序四】：'看看我們的東西被拷貝到哪兒去了
    Sub TestCopyMemory()
        Dim i As Long, k As Long
        k = 5
        i = VarPtr(k)
NOTE4:  CopyMemory i, 40000, 4
        Debug.Print k
        Debug.Print i
        i = VarPtr(k)
NOTE5:  CopyMemory ByVal i, 40000, 4
        Debug.Print k
    End Sub

程序輸出：
5
40000
40000
    由于NOTE4處使用缺省的ByVal，傳遞的是i的地址（也就是指向i的指針），所以常量40000拷貝到了變量i里，因此i的值成了40000，而k的值卻沒有變化。但是，在NOTE4前有：i=VarPtr(k)，本意是要把i本身做為一個指針來使用。這時，我們必須如NOTE5那樣用ByVal來傳遞指針i，由于i是指向變量k的指針，所以最后常量40000被拷貝了變量k里。
    希望你已經理解了這種區別，在后面問題的討論中，我還會再談到它。

4、AddressOf
    它用來得到一個指向VB函數入口地址的指針，不過這個指針只能傳遞給API使用，以使得API能回調VB函數。
    本文不準備詳細討論函數指針，關于它的使用請參考VB文檔。

5、拿來主義。
    實際上，有了CopyMemory，VarPtr，AddressOf這三把斧頭，我們已經可以將C里基本的指針操作拿過來了。
    如下面的C程序包括了大部分基本的指針指針操作：
    struct POINT{
        int x; int y;
    };
    int Compare(void* elem1, void* elem2){}
    void PtrDemo(){
    //指針聲明:
        char c = 'X';        //聲明一個char型變量
        char* pc; long* pl;  //聲明普通指針
        POINT* pPt;          //聲明結構指針
        void* pv;            //聲明無類型指針
        int (*pfnCastToInt)(void *, void*);//聲明函數指針:
    //指針賦值：
       pc = &c;              //將變量c的地址值賦給指針pc
       pfnCompare = Compare; //函數指針賦值。
    //指針取值：
       c = *pc;              //將指針pc所指處的內存值賦給變量c
    //用指針賦值：
       *pc = 'Y'             //將'Y'賦給指針pc所指內存變量里。
    //指針移動：
       pc++; pl--;
    }

    這些對指針操作在VB里都有等同的東西，
    前面討論ByVal和ByRef時曾說過傳指針和傳地址是一回事，實際上當我們在VB里用缺省的ByRef聲明函數參數時，我們已經就聲明了指針。
    如一個C聲明的函數：long Func(char* pc)
    其對應的VB聲明是：Function Func(pc As Byte) As Long
    這時參數pc使用缺省的ByRef傳地址方式來傳遞，這和C里用指針來傳遞參數是一樣。
    那么怎么才能象C里那樣明確地聲明一個指針呢？
    很簡單，如前所說，用一個32位長整數來表達指針就行。在VB里就是用Long型來明確地聲明指針，我們不用區分是普通指針、無類型指針還是函數指針，通通都可用Long來聲明。而給一個指針賦值，就是賦給它用VarPar得到的另一個變量的地址。具體見程序五。
【程序五】：同C一樣，各種指針。
    Type POINT
        X As Integer
        Y As Integer
    End Type
    Public Function Compare(elem1 As Long, elem2 As Long) As Long
    '
    End Function
    Function FnPtrToLong(ByVal lngFnPtr As Long) As Long
        FnPtrToLong = lngFnPtr
    End Function
    Sub PtrDemo()
       Dim l As Long, c As Byte, ca() As Byte, Pt As POINT
       Dim pl As Long, pc As Long, pv As Long, pPt As Long, pfnCompare As Long
       c = AscB("X")
       pl = VarPtr(l)     '對應C里的long、int型指針
       pc = VarPtr(c)     '對應char、short型指針
       pPt = VarPtr(Pt)   '結構指針
       pv = VarPtr(ca(0)) '字節數組指針，可對應任何類型，也就是void*
       pfnCompare = FnPtrToLong(AddressOf Compare) '函數指針
       CopyMemory c, ByVal pc, LenB(c)   '用指針取值
       CopyMemory ByVal pc, AscB("Y"), LenB(c) '用指針賦值
       pc = pc + LenB(c) : pl = pl - LenB(l)   '指針移動
    End Sub
    我們看到，由于VB不直接支持指針操作，在VB里用指針取值和用指針賦值都必須用CopyMemory這個API，而調用API的代價是比較高的，這就決定了我們在VB里使用指針不能象在C里那樣自由和頻繁，我們必須要考慮指針操作的代價，在后面的"指針應用"我們會再變談這個問題。
    程序五中關于函數指針的問題請參考VB文檔，無類型指針void*會在下面"關于Any的問題"里說。
    程序五基本上已經包括了我們能在VB里進行的所有指針操作，僅此而已。

    下面有一個小測試題，如果現在你就弄懂了上面程咬金的三板斧，你就應該能做得出來。
    上面提到過，VB.NET中沒有VarPtr，我們可以用聲明API的方式來引入MSVBVM60.DLL中的VarPtr�，F在的問題如果不用VB的運行時DLL文件，你能不能自己實現一個ObjPtr。答案在下一節后給出。

    四、指針使用中應注意的問題
    1、關于ANY的問題
    如果以一個老師的身份來說話，我會說：最好永遠也不要用Any！是的，我沒說錯，是永遠！所以我沒有把它放在程咬金的三板斧里。當然，這個問題和是不是應該使用指針這個問題一樣會引發一場沒有結果的討論，我告訴你的只是一個觀點，因為有時我們會為了效率上的一點點提高或想偷一點點懶而去用Any，但這樣做需要要承擔風險。
    Any不是一個真正的類型，它只是告訴VB編譯器放棄對參數類型的檢查，這樣，理論上，我們可以將任何類型傳遞給API。
    Any在什么地方用呢？讓我們來看看，在VB文檔里的是怎么說的，現在就請打開MSDN(Visual Studio 6自帶的版本)，翻到"Visual Basic文檔"->"使用Visual Basic"->"部件工具指南"->"訪問DLL和Windows API"部分，再看看"將 C 語言聲明轉換為 Visual Basic 聲明"這一節。文檔里告訴我們，只有C的聲明為LPVOID和NULL時，我們才用Any。實際上如果你愿意承擔風險，所有的類型你都可以用Any。當然，也可以如我所說，永遠不要用Any。   
    為什么要這樣？那為什么VB官方還要提供Any？是信我的，還是信VB官方的？有什么道理不用Any？
    如前面所說，VB官方不鼓勵我們使用指針。因為VB所標榜的優點之一，就是沒有危險的指針操作，所以的內存訪問都是受VB運行時庫控制的。在這一點上，JAVA語言也有著同樣的標榜。但是，同JAVA一樣，VB要避免使用指針而得到更高的安全性，就必須要克服沒有指針而帶來的問題。VB已經盡最大的努力來使我們遠離指針的同時擁有強類型檢查帶來的安全性。但是操作系統是C寫的，里面到處都需要指針，有些指針是沒有類型的，就是C程序員常說的可怕的void*無類型指針。它沒有類型，因此它可以表示所有類型。如CopyMemory所對應的是C語言的memcpy，它的聲明如下：
    void *memcpy( void *dest, const void *src, size_t count );
    因memcpy前兩個參數用的是void*，因此任何類型的參數都可以傳遞給他。
    一個用C的程序員，應該知道在C函數庫里這樣的void*并不少見，也應該知道它有多危險。無論傳遞什么類型的變量指針給上面memcpy的void*，C編譯器都不會報錯或給任何警告。
    在VB里大多數時候，我們使用Any就是為了使用void*，和在C里一樣，VB也不對Any進行類型檢查，我們也可以傳遞任何類型給Any，VB編譯器也都不會報錯或給任何警告。
    但程序運行時會不會出錯，就要看使用它時是不是小心了。正因為在C里很多錯誤是和void*相關的，所以，C++鼓勵我們使用satic_cast<void*>來明確指出這種不安全的類型的轉換，已利于發現錯誤。
    說了這么多C/C++，其實我是想告訴所有VB的程序員，在使用Any時，我們必須和C/C++程序員使用void*一樣要高度小心。
    VB里沒有satic_cast這種東西，但我們可以在傳遞指針時明確的使用long類型，并且用VarPtr來取得參數的指針，這樣至少已經明確地指出我們在使用危險的指針。如程序二經過這樣的處理就成了下面的程序：
【程序五】：'使用更安全的CopyMemory，明確的使用指針！
    Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByVal Destination As Long, ByVal Source As Long, ByVal Length As Long)
    Sub SwapStrPtr2(sA As String, sB As String)
        Dim lTmp As Long
        Dim pTmp As Long, psA As Long, psB As Long
        pTmp = VarPtr(lTmp): psA = VarPtr(sA): psB = VarPtr(sB)
        CopyMemory pTmp, psA, 4
        CopyMemory psA, psB, 4
        CopyMemory psB, pTmp, 4
    End Sub